*
* BOOT MURYADEN FACE2/PLAYER
* (C)1989 BY DECKARD
*
                          ;
         ORG   $800
                          ;
         DFB   1
                          ;
         JSR   $FE89
         JSR   $FE93
         LDX   $2B
         LDA   $C088,X
         TXA
         LSR   A
         LSR   A
         LSR   A
         LSR   A
         ORA   #$C0
         STA   $11
         LDA   #$00
         STA   $10
                          ;
                          ;
         JSR   $FC58
         LDA   #$20
         STA   $E6
         LDX   #$05
         JSR   $F6EC
         LDA   #0
         TAX
         TAY
         JSR   $F411
         JSR   $F3F6
         BIT   $C050
         BIT   $C052
         BIT   $C054
         BIT   $C057
                          ;
                          ;
         LDX   #0
A1       LDA   MESSAGE,X
         BEQ   FINMES
         JSR   $FDED
         INX
         JMP   A1
FINMES   LDA   #$FE
         STA   $0
         EOR   #$FF
         STA   $1
A2       JSR   NOISE
         DEC   $0
         LDA   $0
         EOR   #$FF
         STA   $1
         CMP   #$FE
         BNE   A2
                          ;
         BIT   $C010
         JSR   $FD0C
                          ;
         LDA   #$01
         STA   $0
         EOR   #$FF
         STA   $1
A3       JSR   NOISE
         INC   $0
         LDA   $0
         EOR   #$FF
         STA   $1
         CMP   #$01
         BNE   A3
                          ;
         JSR   $FC58
         JMP   ($0010)
                          ;
NOISE    LDA   $C050
         LDY   #$2
A4       LDX   $0
         LDA   $C030
A5       DEX
         BNE   A5
         DEY
         BNE   A4
         LDA   $C051
         LDY   #2
A6       LDX   $1
         LDA   $C030
A7       DEX
         BNE   A7
         DEY
         BNE   A6
         RTS
                          ;
                          ;
MESSAGE  HEX   8D8D8D8D8D8D8D8D8D8D
         ASC              "PLAYER DISK: MURYADEN"
         HEX   8D8D
         ASC              "(C)1989 BY ELRIK & DECKARD."
         HEX   8D
         HEX   00

         DS    22,0
         ASC   "DECKARD."


         SAV   BOOT/PLAYER
